Code Tuner: Convert MSTest code covarage results in to XML And view through Jenkins

If you are using Jenkins as your CI for a Net project it is not easy to publish code coverage results.In Jenkins without tools such as NCover wich is costly. Instead of this you can do this your own way.
First you need to convert MSTest results in to XML and then to HTML using xstl to publish it as an HTML report in Jenkins.
Step 1

GO to your test local.settings file in visual studio and set it to display the code coverage results an add your required targeted dll's. This is same as configuring visual studio to show the test results and code coverage.
Make sure you have added the test settings file to your version controlling system then it will be in the working space of the jenkins.
Then set path to the MSTest.exe
it may be in your \Microsoft Visual Studio 10.0\Common7\IDE folder

Step 2
Add a windows batch command to run MSTest (after running ms build) and to generate test results file (“reults.trx”) and Coverage report (“data.coverage”)

del results.trx
mstest /testcontainer:Example\TestProject1\bin\debug\TestProject1.dll /resultsfile:results.trx /testsettings:Example\local.testsettings

This will generate a code coverage result in binary format (data.coverage)

Step 3
write a console app to convert binary data.coverage file in to a XML and then it to HTML by xslt and run it after adding windows batch command in jenkins. Here is the example code for console app. Make sure you have add reference to Microsoft.VisualStudio.Coverage.Analysis.dll which you can find in the \Microsoft Visual Studio 10.0\Common7\IDE\PrivateAssemblies folder. And copy Microsoft.VisualStudio.Coverage.Symbols.dll to your bin directory which is also in same folder.

And here is the code of the style.xslt file

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   <xsl:output method="html" indent="yes"/> 
   <xsl:template match="/" >
      <html>
         <head>
            <style type="text/css">
               th {
               background-color:#dcdcdc;
               border:solid 1px #a9a9a9;
               text-indent:2pt;
               font-weight:bolder;
               }
               #data {
               text-align: center;
               }
            </style>
			 
            <script language="JavaScript" type="text/javascript"  >
        
		  function CreateJavescript(){
		  
		  var fileref=document.createElement('script');
          fileref.setAttribute("type","text/javascript");
          fileref.setAttribute("src", "script1.js");
		   document.getElementsByTagName("head")[0].appendChild(fileref);
		  }

</script>
		
            <title>Code Coverage Report</title>
         </head>
         <body onload='CreateJavescript()' >
            <h1>Code Coverage Report</h1>
            <table border="1">
               <tr>
                  <th colspan="3"></th>
                  <th>Name</th>
                  <th>Blocks Covered</th>
                  <th>Blocks Not Covered</th>
                  <th>Coverage</th>
               </tr>
               <xsl:apply-templates select="//CoverageDSPriv/Module" />
            </table>
         </body>
      </html>
   </xsl:template>
 
   <xsl:template match="Module">
      <xsl:variable name="parentId" select="generate-id(./..)" />
      <xsl:variable name="currentId" select="generate-id(.)" />
      <tr id="{$parentId}">
         <td id="{$currentId}"      colspan="3"               onClick="toggleDetail(this)"        onMouseOver="this.style.cursor= 'pointer' ">[+]</td>
         <td><xsl:value-of select="ModuleName" /></td>
         <td id="data"><xsl:value-of select="BlocksCovered" /></td>
         <td id="data"><xsl:value-of select="BlocksNotCovered" /></td>
         <xsl:call-template name="CoverageColumn">
            <xsl:with-param name="covered" select="BlocksCovered" />
            <xsl:with-param name="uncovered" select="BlocksNotCovered" />
         </xsl:call-template>
      </tr>
      <xsl:apply-templates select="NamespaceTable" />
      <tr id="{$currentId}-end" style="display: none;">
         <td colspan="5"></td>
      </tr>
   </xsl:template>
 
   <xsl:template match="NamespaceTable">
      <xsl:variable name="parentId" select="generate-id(./..)" />
      <xsl:variable name="currentId" select="generate-id(.)" />
      <tr id="{$parentId}" style="display: none;">
         <td> - </td>
         <td id="{$currentId}"
               colspan="2"
               onClick="toggleDetail(this)"
               onMouseOver="this.style.cursor= 'pointer' ">[+]</td>
         <td><xsl:value-of select="NamespaceName" /></td>
         <td id="data"><xsl:value-of select="BlocksCovered" /></td>
         <td id="data"><xsl:value-of select="BlocksNotCovered" /></td>
         <xsl:call-template name="CoverageColumn">
            <xsl:with-param name="covered" select="BlocksCovered" />
            <xsl:with-param name="uncovered" select="BlocksNotCovered" />
         </xsl:call-template>
      </tr>
      <xsl:apply-templates select="Class" />
      <tr id="{$currentId}-end" style="display: none;">
         <td colspan="5"></td>
      </tr>
   </xsl:template>
 
   <xsl:template match="Class">
      <xsl:variable name="parentId" select="generate-id(./..)" />
      <xsl:variable name="currentId" select="generate-id(.)" />
      <tr id="{$parentId}" style="display: none;">
         <td> - </td>
         <td> - </td>
         <td id="{$currentId}"
               onClick="toggleDetail(this)"
               onMouseOver="this.style.cursor='pointer' ">[+]</td>
         <td><xsl:value-of select="ClassName" /></td>
         <td id="data"><xsl:value-of select="BlocksCovered" /></td>
         <td id="data"><xsl:value-of select="BlocksNotCovered" /></td>
         <xsl:call-template name="CoverageColumn">
            <xsl:with-param name="covered" select="BlocksCovered" />
            <xsl:with-param name="uncovered" select="BlocksNotCovered" />
         </xsl:call-template>
      </tr>
      <xsl:apply-templates select="Method" />
      <tr id="{$currentId}-end" style="display: none;">
         <td colspan="5"></td>
      </tr>
   </xsl:template>
 
   <xsl:template match="Method">
      <xsl:variable name="parentId" select="generate-id(./..)" />
      <tr id="{$parentId}" style="display: none;">
         <td> -</td>
         <td> - </td>
         <td> - </td>
         <td><xsl:value-of select="MethodName" /></td>
         <td id="data"><xsl:value-of select="BlocksCovered" /></td>
         <td id="data"><xsl:value-of select="BlocksNotCovered" /></td>
         <xsl:call-template name="CoverageColumn">
            <xsl:with-param name="covered" select="BlocksCovered" />
            <xsl:with-param name="uncovered" select="BlocksNotCovered" />
         </xsl:call-template>
      </tr>
   </xsl:template>
 
   <xsl:template name="CoverageColumn">
      <xsl:param name="covered" select="0" />
      <xsl:param name="uncovered" select="0" />
      <td id="data">
         <xsl:variable name="percent"
                              select="($covered div ($covered + $uncovered)) * 100" />
         <xsl:attribute name="style">
            background-color:
            <xsl:choose>
               <xsl:when test="number($percent >= 90)">#86ed60;</xsl:when>
               <xsl:when test="number($percent >= 70)">#ffff99;</xsl:when>
               <xsl:otherwise>#FF7979;</xsl:otherwise>
            </xsl:choose>
         </xsl:attribute>
         <xsl:if test="$percent > 0">
            <xsl:value-of select="format-number($percent, '###.##' )" />%
         </xsl:if>
         <xsl:if test="$percent = 0">
            <xsl:text>0.00%</xsl:text>
         </xsl:if>
      </td>
   </xsl:template>
</xsl:stylesheet>

13 comments:

UnknownApril 12, 2012 at 6:21 PM
Hello!
Could you please share javascript file script1.js. I cannot use generated report without it.
BhanuMarch 20, 2013 at 4:54 PM
i getting the html report but when i am expanding the nodes using + nothing is happening for me. I am expecting it will open the child nodes..please clarify
BhanuMarch 20, 2013 at 6:31 PM
Thanks Jayantha..i made the changes...i am still facing the issue...
my html script tag is like this
script type="text/javascript" src="http://ajax.googleapis.com/ajax/libs/jquery/1.7.2/jquery.min.js"

but when i change this to below manually..it is working
script type="text/javascript" src="http://ajax.googleapis.com/ajax/libs/jquery/1.7.2/jquery.min.js"
/script

but how to get rid of this programatically..I removed < tags in text in order to post..it is not accepting script tags
BhanuMarch 20, 2013 at 6:38 PM
i managed to get it work Jayantha...thanks you very much..it was very helpful
UnknownJanuary 30, 2014 at 2:02 PM
It's very helpful! Can I translate this post into Japanese on my blog? Or Do you know some site which has already done?

Code Tuner

Monday, September 19, 2011

Convert MSTest code covarage results in to XML And view through Jenkins

13 comments:

Total Pageviews

Followers